© Kamal K. Barley, Andreas Ruffing, and Sergei K. Suslov
“Old Quantum Mechanics by Bohr and Sommerfeld from Modern Perspective”

© К. Барли, А. Руффинг, С.К. Суслов
“Старая квантовая механика Бора и Зоммерфельда с современной точки зрения”

Успехи физических наук, Январь 2026 г., Том 196, № 1, с. 83-103

DOI: https://doi.org/10.3367/UFNr.2025.08.040014

(Last modified/executed on December 14, 2026;  12:05 AM Arizona time.)

(*---Constants and Setup---*)(*Pretty print subscript-style variables for display only*)MakeBoxes[nt,StandardForm]:=SubscriptBox["n","t"]
MakeBoxes[nr,StandardForm]:=SubscriptBox["n","r"]

(*Physical constants*)
Z=79; (*Atomic number of Gold, Au*)
α=1/137.036; (*Fine structure constant*)

(*Quantum numbers*)
ntVal=1;
nrVal=1;

(*---Define symbolic formulas as functions---*)

(*Eq.(3.19)*)
ωFunc[nt_]:=Sqrt[nt^2-Z^2 α^2]/nt

(*Eq.(3.20)*)
ϵFunc[nt_,nr_]:=Sqrt[nr] Sqrt[(nr+2 Sqrt[nt^2-Z^2 α^2])]/(nr+Sqrt[nt^2-Z^2 α^2])

(*Eq.(3.21)*)
aFunc[nt_,nr_]:=((nr+Sqrt[nt^2-Z^2 α^2]) Sqrt[Z^2 α^2+(nr+Sqrt[nt^2-Z^2 α^2])^2])/Z

(*---Compute numeric values---*)

ωVal=ωFunc[ntVal]//N
ϵVal=ϵFunc[ntVal,nrVal]//N
aVal=aFunc[ntVal,nrVal]//N
{rMin=aVal*(1-ϵVal) //N, rMax=aVal*(1+ϵVal) //N}
DeltaOmega=2*Pi*((1/ωVal) -1) //N

(*---Define relativistic radial orbit r(t) from Eq.(3.9)---*)
r[t_]:=(aVal (1-ϵVal^2))/(1+ϵVal Cos[ωVal t])

(*---Polar plot the relativistic elliptical orbit---*)
PolarPlot[r[t],{t,0,2Pi},PlotLabel->"Relativistic Elliptical Orbit",AxesLabel->{"x","y"},PlotRange->All,PlotStyle->Thick]
(*---Polar plot the relativistic elliptical orbit---*)
PolarPlot[r[t],{t,0,4 Pi},PlotLabel->"Relativistic Elliptical Orbit",AxesLabel->{"x","y"},PlotRange->All,PlotStyle->Thick]
PolarPlot[r[t],{t,0,6 Pi},PlotLabel->"Relativistic Elliptical Orbit",AxesLabel->{"x","y"},PlotRange->All,PlotStyle->Thick]

(*Animation in Cartesian Coordinates*)Manipulate[ParametricPlot[{r[t] Cos[t],r[t] Sin[t]},{t,0,tMax},PlotStyle->{Blue,Thick},AxesLabel->{"x","y"},PlotLabel->Style["Relativistic Elliptical Orbit (Animated, Cartesian)",14,Bold],PlotRange->{{-0.084,0.084},{-0.084,0.084}},(*Fixed range ensures full visibility from (Subscript[r, min])=0.004683 to (Subscript[r, max])=0.083014*)AspectRatio->1,PlotPoints->1000,PerformanceGoal->"Quality"],{tMax,0.1,23 Pi,Appearance->"Labeled"}]

Summary: 
In the above animation of the relativistic Kepler motion of an electron in hydrogen-like gold ion, Au, when Z=79, the nucleus is situated  in the fixed focus at the origin.  For this quantum state, we choose (Subscript[n, r])=nr=1 and (Subscript[n, θ])=nt=1 in the fine structure formula (3.18). By (3.19)-(3.21), one gets: ω=0.817104,  ϵ=0.893193, and a=0.0438488, in Bohr’s atomic units. 
The perihelion and aphelion move along two concentric circles around the nucleus with radii:  (Subscript[r, min])=a (1-ϵ)=0.004683 and (Subscript[r, max])=a (1+ϵ)=0.083014, respectively.  In the animation, the geometrical loci of the successive perihelia and aphelia, the outer and inner envelopes of the orbit, see Figure 3, are not shown for simplicity.
Rotation of the ellipse over one period is given by Δθ=2π(1/ω-1)=1.4064.